here is an game i coded originally in qb64 which i converted into fb.
in the game you are the Israeli prime minister and you need to make decisions about economic diplomatic and military issues.
the game does not give proper score for your actions and you are not judged for your achievements or failures since "only history can judge you"
this game is a homage to the 1990 dos game "CONFLICT - middle east political simulator"...
https://en.wikipedia.org/wiki/Conflict: ... _Simulator
Code: Select all
#lang"qb"
'_TITLE "CONFLICT - SIMULATION GAME V.09" 'started by ron77 on 11-12-2019 - made a working skeleton of subs... need more work to be complited
'11-16-2019 continuing working on the game with help of bplus and my teacher. added functions for more options bottens...
'added time scale for how long the game will be played...
'11-18-2019 added military-opration option to in military menu seem to be working good
'my english is not good i make spelling mistakes but that'a what you get when you code at nights and don't sleep enough hours :(
'added bplus date1$ functions
'11-24-2019 added more options now to add score variables to finish this game
'first version prototype is ready
'04-01-2020 converted to freebasic (#lang"qb")
REDIM SHARED news$(0) ', un$(0)
DIM SHARED TypeGovernment$, MilitaryAction$, ForeignAction$, EconomicAction$, PeaceButtonIndicator AS INTEGER, PeaceProssessCounter AS INTEGER
DIM SHARED time AS Integer, MilitaryButtonIndicator AS INTEGER, MilitarytCounter AS INTEGER, GameOver AS INTEGER, MCounter%, FCounter%, Defense%, Taxs%, Bo%, Us%, Un%
Randomize Timer
Screen 0
Dim Shared month2$(1 To 12)
'cp needs s$ to be less that width of screen
'SUB cp (row, s$)
' LOCATE row, INT((_WIDTH - LEN(s$)) / 2): PRINT s$;
'END Sub
Sub cp (row, s$)
LOCATE row, (80 - LEN(s$)) / 2: PRINT s$
END Sub
SUB lp (row, col, s$)
LOCATE row, col: PRINT s$;
END Sub
FUNCTION GetKey$ (keysToCatch$)
DIM k$
DO
k$ = INKEY$
WHILE LEN(k$) = 0
k$ = INKEY$
Sleep 1 '<-----added this so not 100% cpu usage
WEND
LOOP UNTIL INSTR(keysToCatch$, k$)
GetKey$ = k$
END FUNCTION
FUNCTION Month$ (n) 'for dates1$ function
RESTORE 4
FOR i = 1 TO n
READ Month2$(i)
NEXT
Month$ = Month2$(n)
END FUNCTION
4 DATA "JANUARY","FEBRUARY","MARCH","APRIL","MAY","JUNE","JULY","AUGUST","SEPTEMBER","OCTOBER","NOVEMBER","DECEMBER"
FUNCTION dates1$ (months As Integer)
M = months MOD 12
IF M = 0 THEN M = 12
dates1$ = Month$(M) + "," + STR$(INT((months - 1) / 12) + 2027)
END Function
FUNCTION peace$ (n As Integer) ' how to make a function out of a string array!!!
Select CASE n
CASE 1: peace$ = "WE HAVE STARTED TO NEGOTIATE SECRETLY WITH THE IRANIANS. PROGRESS IS SLOW. IT WILL TAKE TIME"
CASE 2: peace$ = "WE ARE NEGOTIATING WITH THE IRANIANS BUT IT LOOKS LIKE THEY ARE DELAYING ON PURPOSE TIME WHILE THE NEGOTIATION IS STUCK"
CASE 3: peace$ = "THERE IS CONCERN THAT THE SECRET CHANNEL BETWEEN US AND THE IRANIANS WILL LEAK TO THE PRESS. IF SO THIS MAY PUT AN END TO THE NEGOTIATIONS"
CASE 4: peace$ = "THE NEGOTIATION TEAMS BETWEEN US AND IRAN HAVE DONE SOME PROGRESS... WE NEED MORE TIME"
CASE 5: peace$ = "WE ARE CLOSE TO A PEACE AGREEMENT BETWEEN US AND THE IRANIANS TO END ALL HOSTILITY JUST A FEW MORE DETILES"
CASE 6: peace$ = "WE HAVE A PEACE AGREEMENT READY BETWEEN US AND THE IRANIANS - ARE YOU READY TO SIGN IT?"
CASE 7: peace$ = "WE HAVE SIGN A PEACE AGREEMENT WITH IRAN\HAMAS\HIZZBALLA. NOT MORE WAR NO MORE BLOODSHED!"
END SELECT
END FUNCTION
FUNCTION Speech$ (n As Integer)
SELECT CASE n
CASE 1: Speech$ = "YOU GIVE A CHARISMATIC SPEECH IN THE U.N. COUNCIL WHICH LEAVES THE WORLD SPEECHLESS. WHEN YOU FINISH THERE ARE APPLAUSE"
CASE 2: Speech$ = "YOU GIVE A WEAK AND PAILE SPEECH IN THE U.N. THE ISRAELIS START TO QUESTION YOUR ABILLITIES TO LEAD THEM"
CASE 3: Speech$ = "YOU GIVE AN ORDINARY POLITICAL SPEECH WHICH CONVINCE ONLY THOSE YOU ARE ALREADY PRO-ISRAELIS. YOUR SPEECH GOOD BUT HAS NO IMPACT"
END SELECT
END FUNCTION
FUNCTION Operation$ (n As Integer)
SELECT CASE n
CASE 1: Operation$ = "WE HAVE STARTED A MILITARY OPERATION AGAINS HAMAS AND HIZZBALLA. WE ARE BOMBING TARGETS WHILE HAMAS AND HIZZBALLA ARE LUNCHING MISSILES AT OUR CIVILIAN POPULATION. SO FAR THE CASAULTEIS ON BOTH SIDES ARE A FEW DOZENS"
CASE 2: Operation$ = "THE ENEMY'S ROCKETS AND MISILES ARE INTERSEPED BY OUR IRON DOME ANTI MISSLES SYSTEM YET THE CASUALTIES ARE INCREASING. WORLD OPINION IS TURNING AGAINST US AS THEY SEE ISRAEL AS THE AGRESSER. WE ARE DESTROYING TERROR INFUSTRACTIONS, EMEMY BASES AND MILITARY TARGETS"
CASE 3: Operation$ = "BOTH ISRAELIES AND ARAB POPULATIONS ARE TIERD FROM THIS OPERATION AND SO IS THE WORLD OPINION HAS TURNED AGAIST US. WE HAVE DONE THE MAXIMUN DAMEGE WE COULD TO HAMAS AND HIZZBALLA WITHOUT SENDING TROOPS ON THE GROUND"
CASE 4: Operation$ = "THIS OPERATION SEEMS ENDLESS CASUALTIES ON BOTH SIDES HAVE INCREASED TO HUNDREADS... THIS OPERATION HAS REACHED IT'S TARGET. HAMAS AND HIZZBALLA MILITARY ABBILITIES HAS BEEN DESTROYED OR SEVERLY DAMEDGED AND OUR DETERENT HAS BEEN RESTORED IT'S SEEM LIKE THE RIGHT TIME TO SIGN A A CEASEFIRE AGREEMENT"
CASE 5: Operation$ = "WE CURENTLLY HAVE A CEASEFIRE AGREEMNENT WITH HAMAS AND HIZZBALLA"
END SELECT
END FUNCTION
FUNCTION UnCouncil$ (n As Integer)
'REDIM un$(1 TO 4)
SELECT CASE n
CASE 1: UnCouncil$ = "THE U.N. COUNCIL HAS REJECTED OUR REQUEST FOR CONDEMMING IRAN OR HAMAS OR HIZZBLLA"
CASE 2: UnCouncil$ = "THE U.N. COUNCIL HAS REVERSED OUR REQUEST AND ADOPTED THE INDONASIAN'S REQUEST FOR CONDOMMING ISRAEL AS AN AGGRESSIVE APARTHIDE RACIST STATE"
CASE 3: UnCouncil$ = "OUR REQUEST HAS REACHED TO THE SECURITY COUNCIL OF THE U.N. BUT A VETO BY RUSSIA AND CHINA HAS CANCELED ANY CHANCE OF CONDEMMING IRAN OR HIZZBALLA OR HAMAS AS TERROR ORGANIZATIONS"
CASE 4: UnCouncil$ = "THE SECURITY COUNCIL OF THE U.N. HAD VOTED AGAINST IRAN AND HIZZBALLA AND HAMAS CALLING THEM A TERROR ORGANIZATIONS AND SAYING THAT ISRAEL HAS A RIGHT TO DEFEND ITSELF AND IT'S CITIZENS"
END SELECT
End Function
FUNCTION UsAid$ (n As Integer)
SELECT CASE n
CASE 1: UsAid$ = "IT IS AN ELECTION YEAR IN THE USA SO YOU ARE SUCCESSFUL IN WINING SUPPORT FOR ISRAEL SENATORS AND CONGRESSMANS PROMISS TO INCRESS AID AND SUPPORT FOR ISRAEL AND AGINST IRAN AND HAMAS AND HIZZBALLA"
CASE 2: UsAid$ = "THE US CONGRESS AND SENATE PASS A LAW TO BAN IRAN AND HAMAS AND HIZZBALLA AND DECLEARE THEM AS TERROR ORGANIZATIONS"
CASE 3: UsAid$ = "YOU ARE INVITED TO THE WHITE HOUSE FOR AN PHOTO-OP WITH THE U.S. PRESIDENT BESIDES THAT YOU ACHIVE ALMOST NOTHING 'WE SUPPORT YOU AND AID YOU ENOGH' SAYS TO YOU THE PRESIDENT BEHIND CLOSE DOORS"
CASE 4: UsAid$ = "THE U.S. PRESIDENT APPEARS IN A PRESS CONFFERENCE AND DECLEARES 'ISRAEL HAS THE RIGHT TO DEFEND ITSELF AND ISRAELIS HAVE A RIGHT TO LIVE IN PEACE AND SECURITY'"
CASE 5: UsAid$ = "THE U.S.A. IS OCCUPY BY IT'S OWN PROBLEMS. THE U.S. AMBASSADOR TELLS YOU IT'S NOT A GOOD TIME TO ASK FOR AID OF ANY KIND FROM THE U.S."
CASE 6: UsAid$ = "THE U.S.A. GOVERNMENT DICIDED TO INCREASE IT'S FOREIGN AID TO ISRAEL"
END SELECT
END FUNCTION
FUNCTION Asasination$ (n As Integer)
SELECT CASE n
CASE 1: Asasination$ = "WE HAVE SUCCEDED IN ASSASINATING A KEY FIGURE IN HAMAS ROCKET MILITARY INDUSTRY. THIS WILL DELAY THE ABBILITIES OF HAMAS ROCKETS TO REACH DEEP INTO ISRAEL IN CASE OF WAR"
CASE 2: Asasination$ = "WE SUCCEDED IN ELIMINATING THE HEAD OF THE IRANINAN NUCLEAR PROJECT, HOWEVER THE OPERATION DID NOT GO SO WELL ONE AGENT WAS CAPTURED BY THE IRANIAN AT THE BORDER"
CASE 3: Asasination$ = "WE FAILED TO ELIMINATE HIZZBALLA'S CHIFF OF STAFF. AND NOW HE HAS GONE UNDERGROUND, ALSO WE LOST 2 AGENTS WHO WHERE CAPTURED"
CASE 4: Asasination$ = "WE TRIED TO GET OUR HANDS ON HAMAS KEY FIGURE IN THEIR MILITARY ARMS BUT HE ESCAPED AT THE LAST MOMENT, WE HAD TO CANCEL THE OPERATION AT THE LAST MOMENT"
CASE 5: Asasination$ = "WE SUCCEDED IN ASSASINATING A HIZZBALLA'S COLONEL IN SYRIA, THE OPERATION WAS A SUCCESS"
END SELECT
END FUNCTION
FUNCTION BOMB$ (n As Integer)
SELECT CASE n
CASE 1: BOMB$ = "WE SUCCEDED IN DESTROYING IRAN NUCLEAR FACILITIES, THIS SHOULD PREVENT FROM IRAN TO REACH AN ATOMIC BOMB FOR A FEW MORE YAERS"
CASE 2: BOMB$ = "THE OPERATION WAS A TOTAL FAILURE, POOR INTELLIGENCE AND LUCK OF PROPER EQUIPMENT RESULTED IN 12 AIRCRAFTS LOST AND THE PILOTS HAVE BEEN KILLED OR CAPTURED BY THE IRANIANS"
CASE 3: BOMB$ = "THE OPERATION WAS PARTLY SUCCESSFUL THE MAIN TARGET WAS DESTROYED BUT WE LOST 4 AIRCRAFTS AND THE PILOTS HAVE BEEN CAPTURED BY THR IRANIANS"
END SELECT
END FUNCTION
SUB loadNews 'don't try to cp these lines, they are too long
REDIM news$(1 TO 9)
news$(1) = "HAMAS HAS LUNCHED MISSILES TO THE SOUTHEREN BORDER THE PUBLIC DEMANDS ACTION"
news$(2) = "HIZZBALLA HAS ATTACKED A BASE NEAR THE NORTHEN BORDER 2 OF OUR SOLDIERS ARE MISSING - WHAT SHELL BE OUR RESPONSE?"
news$(3) = "IRAN IS BUILDING A NUCLEAR SITE FOR PLUTONIUM WITHIN A FEW YEARS THEY WILL HAVE AN ATOMIC WEPONE AGAINST US - WE MUST DO SOMETHING!"
news$(4) = "HAMAS HAS SECRETLY CONTACTED THE FORINE AFFAIRS OFFICE WITH A MESSAGE THEY WANT PEACE AND STABILITY - SHELL WE NEGOTIATE?"
news$(5) = "THE U.S. PRESIDENT HAS ASKED US TO CONSIDER A PEACE DEAL WITH IRAN - IN RETURN THE U.S. WILL EQUIPTE OUR ARMY WITH THE LATEST WEPONES AND INCREASE THE MILITERY AID"
news$(6) = "OUR ECONOMY IS NOT DOING GOOD WE SPEND TOO MUCH MONEY ON THE MILITERY - WE NEED TO CHOOSE EITHER MORE TAXS OR DECREASE SPENDING"
news$(7) = "IRAN PRESIDENT HAS SAID THAT 'ISRAEL MUST AND WILL BE ERASED FROM THE MAP!' - HOW SHELL WE RESPOND TO THIS PROVOCATION?"
news$(8) = "IRANIAN DIPLOMATES HAVE CONTACTED THE FORINE AFFAIRS AMBASSADOR IN CHILE AND ASKED TO OPEN A SECRET NEGOTIATION - SHELL WE AGREE?"
news$(9) = "OUR ECONOMY IS BOOMING AND FLURISHING WE NEED TO DISIDE EITHER TO INCREASE DEFENCE BUDGET OR MAYBE DECRESE TAXS"
END SUB
SUB Opening
CLS
cp 4, "CONFLICT - STRATEGIC POLITICAL SIMULATION"
cp 6, "BY RON77 AND Bplus AND ITAY"
COLOR 31: cp 8, "PRESS ANY KEY 1 TO BEGIN OR ESC KEY TO EXIT": COLOR 7
k$ = GetKey$("1" + CHR$(27))
IF k$ = CHR$(27) THEN END
CLS
cp 3, "YOU ARE THE NEWLY ELECTED PRIME MINISTER OF THE STATE OF ISRAEL"
cp 5, "YOU PROMISSED THE ISRAELI VOTERS - 'PEACE AND SECURITY'"
cp 7, "HOWEVER THE MIDDLE EAST IS BURNING FROM TERROR AND INSTABILITY"
cp 9, "HAMAS FROM GAZA AND HIZZBALLA FROM LEBANON AND IRAN ARE THRETHENING"
cp 11, "TO DESTROY ISRAEL AND KILL ALL ISRAELIS"
cp 13, "THE FAITH OF THE ISRAELI NATION IS IN YOUR HANDS"
cp 15, "MAY GOD BE WITH YOU! - GOOD LUCK!"
cp 19, "press any to continue..."
SLEEP
CLS
cp 3, "WHAT TYPE OF GOVERNMENT WILL YOU MAKE?"
lp 5, 2, "1. MAKE A LEFT WING GOVERNMENT AND TRY TO ACHIVE PEACE WITH THE ARAB WORLD"
lp 6, 2, "2. MAKE A CONSERVATIVE CENTER GOVERNMENT THAT WILL TRY TO MAINTAINE STABILITY"
lp 7, 2, "3. MAKE A RIGHT WING GOVERNMENT THAT WILL FIGHT ISRAEL'S ENEMIES"
cp 9, "PLEASE CHOOSE 1 2 OR 3 KEYS"
TypeGovernment$ = GetKey$("123") '>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> where does this get used????
END SUB
SUB Military
SELECT CASE MilitaryButtonIndicator
CASE 1: OperationButten$ = "2. OPEN A LIMITED MILITARY OPERATION AGAINST HAMAS\HIZZBALLA"
CASE 2: OperationButten$ = "2. SIGN A CEASEFIRE AGREEMENT AND STOP MILITARY OPERATION"
END SELECT
IF MilitaryButtonIndicator = 2 AND MilitarytCounter < 4 THEN
o$ = Operation$(MilitarytCounter)
MilitarytCounter = MilitarytCounter + 1
ELSEIF MilitarytCounter >= 4 THEN
o$ = Operation$(MilitarytCounter)
END IF
CLS
cp 2, "THE MILITARY IS WAITING FOR YOUR ORDERS SIR!"
lp 4, 2, "1. ASSASINATE A KEY FIGURE IN HAMAS\HIZZBALLA\IRAN MILITERY ORGANIZATION"
lp 5, 2, OperationButten$
lp 6, 2, "3. BOMB STRATEGIC TARGETS IN IRAN TO DESTROY NUCLEAR FACILITIES"
lp 7, 2, "4. DO NOTHING FOR THE MOMENT - LET'S WAIT AND SEE HOW THINGS DEVELOP"
cp 9, "CHOOSE 1 2 3 OR 4 KEYS"
PRINT
PRINT o$
PRINT
MilitaryAction$ = GetKey$("1234")
IF MilitaryAction$ = "2" AND MilitaryButtonIndicator = 1 THEN
MilitarytCounter = 1
MilitaryButtonIndicator = 2
MCounter% = MCounter% + 1
ELSEIF MilitaryAction$ = "2" AND MilitaryButtonIndicator = 2 THEN
MilitaryButtonIndicator = 1
MilitarytCounter = 5
END IF
IF MilitaryAction$ = "1" THEN
PRINT Asasination$(INT(RND * 5) + 1)
PRINT
SLEEP
END IF
IF MilitaryAction$ = "3" THEN
Bo% = Bo% + 1
PRINT BOMB$(INT(RND * 3) + 1)
PRINT
SLEEP
END IF
END SUB
SUB Foreign
IF PeaceButtonIndicator = 2 AND PeaceProssessCounter < 6 THEN
p$ = peace$(PeaceProssessCounter)
'PRINT p$
PeaceProssessCounter = PeaceProssessCounter + 1
ELSEIF PeaceProssessCounter >= 6 THEN
p$ = peace$(PeaceProssessCounter)
END IF
SELECT CASE PeaceButtonIndicator
CASE 1: PeaceButton$ = "1. START A SECRET NEGOTIOATION CHANNEL WITH HAMAS\HIZZBALLA\IRAN"
CASE 2: PeaceButton$ = "1. WE ARE NEGOTITATHING SECRETLY WITH THE IRANIANS, SHELL WE STOP?"
CASE 3: PeaceButton$ = "1. SIGN A PEACE AGREEMENT WITH IRAN\HAMAS\HIZZBALLA"
CASE 4: PeaceButton$ = "1. BREAK THE PEACE AGREEMENT WITH IRAN\HAMAS\HIZZBALLA"
END SELECT
CLS
cp 2, "FOREIGN AFFAIRS MINISTER AT YOUR SERVICE. SIR!"
lp 4, 2, PeaceButton$
lp 5, 2, "2. ASK THE U.N. SECURITY COUNCIL TO CONDEMN AND SANCTION IRAN\HAMAS\HIZZBALLA"
lp 6, 2, "3. ASK THE U.S. FOR AID"
lp 7, 2, "4. TRY TO INCREASE WORLD SUPPORT FOR ISRAEL BY MAKING A SPEECH IN THE U.N."
lp 8, 2, "5. DO NOTHING FOR THE MOMENT - LET'S WAIT AND SEE HOW THINGS DEVELOP"
cp 10, "CHOOSE 1 2 3 4 OR 5"
PRINT
PRINT p$
PRINT
ForeignAction$ = GetKey$("12345")
IF ForeignAction$ = "1" AND PeaceButtonIndicator = 1 THEN
PeaceButtonIndicator = 2
ELSEIF ForeignAction$ = "1" AND PeaceButtonIndicator = 2 AND PeaceProssessCounter < 6 THEN
PeaceButtonIndicator = 1
PeaceProssessCounter = 1
ELSEIF PeaceButtonIndicator = 2 AND PeaceProssessCounter = 6 THEN
PeaceButtonIndicator = 3
ELSEIF ForeignAction$ = "1" AND PeaceButtonIndicator = 3 THEN
PeaceButtonIndicator = 4
PeaceProssessCounter = 7
FCounter% = FCounter% + 1
ELSEIF ForeignAction$ = "1" AND PeaceButtonIndicator = 4 THEN
PeaceButtonIndicator = 1
PeaceProssessCounter = 1
END IF
IF ForeignAction$ = "2" THEN
Un% = Un% + 1
PRINT UnCouncil$(INT(RND * 4) + 1)
PRINT
SLEEP
END IF
IF ForeignAction$ = "3" THEN
Us% = Us% + 1
PRINT UsAid$(INT(RND * 6) + 1)
PRINT
SLEEP
END IF
IF ForeignAction$ = "4" THEN
PRINT Speech$(INT(RND * 3) + 1)
PRINT
SLEEP
END IF
END SUB
SUB Economics
CLS
cp 2, "THE ECONOMIC CABINET IS READY TO MEET YOU PRIME MINISTER"
lp 4, 2, "1. INCREASE DEFENCE BUDGET AND RAISE TAXS"
lp 5, 2, "2. DECREASE DEFENCE BUDGET AND LOWER TAXS"
lp 6, 2, "3. LEAVE THE BUDGET AS IT IS FOR NOW"
lp 7, 2, "4. EXIT GAME"
lp 10, 2, "CHOOSE 1 2 3 OR 4"
EconomicAction$ = GetKey$("1234")
IF EconomicAction$ = "4" THEN
'CLS
GameOver = -1
EXIT SUB
END IF
IF EconomicAction$ = "1" THEN
Taxs% = Taxs% + 1
PRINT: PRINT
PRINT "THERE ARE WIDE SPREAD DEMONSTRATIONS ACROSS THE CONTREY BY ISREALI CITIZENS DEMANDING YOUR RESIGNATION AND SOCIAL JUSTISE AND 'NO MORE TAXS!'"
SLEEP
DO
LOOP UNTIL INKEY$ <> "0"
END IF
IF EconomicAction$ = "2" THEN
Defense% = Defense% + 1
PRINT: PRINT
PRINT "THIS WILL BENIFIT THE ISRAELI PUBLIC HOWEVER OUR SECURITY FORCES WILL BE UNABLE TO PROTECT OR GIVE PROPER SECURITY TO THE STATE"
SLEEP
DO
LOOP UNTIL INKEY$ = ""
END IF
END SUB
FUNCTION NewsUpdate$ ()
'cp 2, dates1$(time)
'PRINT
NewsUpdate$ = news$(INT(RND * 9) + 1)
'time = time + 1
END FUNCTION
Sub ending
CLS
cp 2, "GAME OVER"
SELECT CASE TypeGovernment$
CASE "1": GovType$ = "LEFT WING LIBERAL PRO PEACE"
CASE "2": GovType$ = "CONSERVATIVE CENTERED"
CASE "3": GovType$ = "RIGHT WING EXTREAMISTS"
END SELECT
cp 4, "YOU AS A PLAYER FORMED A " + GovType$ + " GOVERNMENT"
cp 6, "YOU WENT TO FIGHT ISRAEL EMENIES " + STR$(MCounter%) + " TIMES"
cp 8, "YOU ORDERED TO BOMB IRAN'S NUCLEAR FACILITIES " + STR$(Bo%) + " TIMES"
cp 10, "YOU SIGN " + STR$(FCounter%) + " PEACE AGREENMENTS"
cp 12, "YOU ASKED " + STR$(Un%) + " TIMES HELP FROM THE U.N."
cp 14, "AND ASKED FOR AID " + STR$(Us%) + " FROM THE U.S.A."
cp 16, "YOU RAISED TAXS " + STR$(Taxs%) + " TIMES ON THE ISRAELI ECOMOMY"
cp 18, "YOU LOWER THE DEFENCE BODGET " + STR$(Defense%) + " TIMES"
cp 20, "SO HOW DID YOU PLAY??? - ONLY HISTORY SHELL AND CAN JUDGE YOU"
COLOR 31: cp 22, "PLAY AGAIN? (y/n)?:": COLOR 7
'DO
'LOOP UNTIL INKEY$ = ""
'SLEEP
'IF INKEY$ = LCASE$("n") THEN END
'again$ = GetKey$("ny")
END SUB
DO
PeaceButtonIndicator = 1
PeaceProssessCounter = 1
MilitaryButtonIndicator = 1
MilitarytCounter = 1
time = 1
GameOver = 0
MCounter% = 0
FCounter% = 0
Defense% = 0
Taxs% = 0
Bo% = 0
Un% = 0
Us% = 0
loadNews
Opening
DO
CLS
cp 2, dates1$(time): PRINT: PRINT
time = time + 1
PRINT NewsUpdate$
PRINT: INPUT "Press enter when you have read the latest news... "; wayt$
Military
Foreign
Economics
'cp 6, "GAME OVER"
LOOP UNTIL time = 49 OR GameOver = -1
ending
again$ = GetKey$("ny")
LOOP UNTIL again$ = LCASE$("n")